Windows and Linux Networking: Search user in Active Directory with First and Last Name using VBScript.

Tuesday, June 21, 2011

Search user in Active Directory with First and Last Name using VBScript.

Search user in Active Directory with First and Last Name using VBScript.

Suppose you want all users’ data with Fist Name, Last Name, Login Name and Email address of user. Here is a VBScript that search for all users and get required information.

Option Explicit

Dim adocommand, adoconnection, strBase, strFilter, strAttributes

Dim objRootDSE, strDNSDomain, strQuery, adoRecordset, strName, strCN , strGivenNAme ,strSN, strmail

'Setup ADO Objects.

Set adocommand = CreateObject("ADODB.Command")

Set adoConnection = CreateObject("ADODB.Connection")

adoConnection.Provider = "ADsDSOobject"

adoConnection.Open "Active Directory Provider"

Set adoCommand.ActiveConnection = adoConnection

' Search entire Active Directory Domain

Set objRootDSE = GetObject("LDAP://RootDSE")

strDNSDomain = objRootDSE.Get("defaultNamingContext")

strBase = "<LDAP://" & strDNSDomain & ">"

' Filter on user objects.

strFilter = "(&(objectCategory=person)(objectClass=user))"

'Comma delimited list of attribute values to retrieve.

strAttributes = "sAMAccountName,cn,givenName,sn,mail"

'Constuct the LDAP syntax query

strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"

adocommand.commandText = strQuery

adoCommand.Properties("Page Size") = 100

adoCommand.Properties("TimeOut") = 30

adoCommand.properties("Cache Results") = False

' Run the query

Set adoRecordset = adoCommand.Execute

' Enumerate the resulting recordset.

Do Until adoRecordset.EOF

' Retrieve values and display.

strName = adoRecordset.Fields("sAMAccountName").Value

strCN = adoRecordset.Fields("cn").Value

strGivenName = adoRecordset.Fields("givenName")

strSN = adoRecordset.Fields("sn").Value

strmail = adoRecordset.Fields("mail").Value

WScript.Echo "First Name: " & strGivenName & ", Last Name: " & strSN & ", User Login Name: " & strName & ", Email Address:" & strmail

'Move to the Next Record in the recordset.

adoRecordSet.MoveNext

Loop

'Clean up.

adoRecordSet.Close

adoConnection.Close

In this script you can make some changes If you want to search use with Fist and last name. Suppose we want to search for user whoes First name is Sandeep and Last name is kapadane. for that we have to only need to add filter on previous script.